; $Id: declination.pro,v 5.4 11/7/2001
;
; Copyright (c) 2001 Javier G Corripio.  
;  jgc@geo.ed.ac.uk
;+
; NAME:
;	declination
;
; PURPOSE:
;	computes declination for a given Julian day 
;
; CATEGORY:
;	Astronomy
;
; CALLING SEQUENCE:
;	RESULT = declination(Jday,year)
;
; INPUTS:
;	 Jday: Day of the year (1 = 1/January, 365 = 31/December)
;	 Year
;
; OUTPUTS:
;	
;	solar declination in degrees
;
;
; MODIFICATION HISTORY:
;	Created Javier Corripio, August, 2001 
;
;-

FUNCTION declination,Jday,year   

;** dayang=w*t & w=(360.0/365.25)
;** t=Julian Day-0.5-J0
;** J0=78.801+0.2422*(Year-1969)-INT(0.25*(Year-1969))
;** so for 2001 J0 = 79.0514

 w=(360.0/365.25)
 J0=78.801+0.2422*(Year-1969)-FIX(0.25*(Year-1969))
 t=Jday-0.5-J0
 dayang=w*t 

dayang = dayang/!RADEG

;*** Declination: Bourgues, 1985

 delta = 0.3723 $			
       + 23.2567*SIN(dayang)  - 0.758*COS(dayang) $
       + 0.1149*SIN(2*dayang) + 0.3656*COS(2*dayang) $
       - 0.1712*SIN(3*dayang) + 0.0201*COS(3*dayang)

delta = delta/!RADEG

RETURN,delta

END